Deliverable Templates

Architecture Definition Document

The primary ArchiMate 4.0 deliverable documenting the target architecture across business, application, and technology domains. Uses the domain-based structure of ArchiMate 4.0 with merged cross-domain behavior elements.

Template: templates/architecture-definition-document.md.hbs

Required Viewpoints: Organization ProcessCooperationVP ApplicationStructureVP TechnologyVP LayeredVP ImplementationDeploymentVP

Target Purposes: Designing, Informing

Available Formats: MarkdownFormat, HTMLFormat, PDFFormat

Sections

1 1. Business Domain

Business actors, roles, collaborations, and organizational structure.

Viewpoint: Organization Result key: businessDomain

SPARQL Query

PREFIX am4:  <https://meta.linked.archi/archimate4/onto#>
PREFIX arch: <https://meta.linked.archi/core#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?element ?label ?type ?description ?assignedTo WHERE {
    ?element a ?type ; skos:prefLabel ?label .
    VALUES ?type {
        am4:BusinessActor am4:Role am4:Collaboration
        am4:BusinessInterface am4:Location
    }
    OPTIONAL { ?element skos:definition ?description }
    OPTIONAL {
        ?element am4:assignedTo ?target .
        ?target skos:prefLabel ?assignedTo .
        FILTER(lang(?assignedTo) = "en")
    }
    FILTER(lang(?label) = "en")
} ORDER BY ?type ?label

2 2. Process Cooperation

Cross-domain processes, functions, events, services, and their interactions.

Viewpoint: ProcessCooperationVP Result key: processCooperation

SPARQL Query

PREFIX am4:  <https://meta.linked.archi/archimate4/onto#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?element ?label ?type ?description ?flowsTo ?serves WHERE {
    ?element a ?type ; skos:prefLabel ?label .
    VALUES ?type {
        am4:Process am4:Function am4:Event am4:Service
        am4:BusinessObject am4:DataObject
    }
    OPTIONAL { ?element skos:definition ?description }
    OPTIONAL {
        ?element am4:flowsTo ?ft .
        ?ft skos:prefLabel ?flowsTo .
        FILTER(lang(?flowsTo) = "en")
    }
    OPTIONAL {
        ?element am4:serves ?sv .
        ?sv skos:prefLabel ?serves .
        FILTER(lang(?serves) = "en")
    }
    FILTER(lang(?label) = "en")
} ORDER BY ?type ?label

3 3. Application Domain

Application components, interfaces, and data objects.

Viewpoint: ApplicationStructureVP Result key: applicationDomain

SPARQL Query

PREFIX am4:  <https://meta.linked.archi/archimate4/onto#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?element ?label ?type ?description ?serves ?accesses WHERE {
    ?element a ?type ; skos:prefLabel ?label .
    VALUES ?type {
        am4:ApplicationComponent am4:ApplicationInterface am4:DataObject
    }
    OPTIONAL { ?element skos:definition ?description }
    OPTIONAL {
        ?element am4:serves ?sv .
        ?sv skos:prefLabel ?serves .
        FILTER(lang(?serves) = "en")
    }
    OPTIONAL {
        ?element am4:accesses ?ac .
        ?ac skos:prefLabel ?accesses .
        FILTER(lang(?accesses) = "en")
    }
    FILTER(lang(?label) = "en")
} ORDER BY ?type ?label

4 4. Technology Domain

Nodes, devices, system software, networks, equipment, facilities.

Viewpoint: TechnologyVP Result key: technologyDomain

SPARQL Query

PREFIX am4:  <https://meta.linked.archi/archimate4/onto#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?element ?label ?type ?description ?assignedTo WHERE {
    ?element a ?type ; skos:prefLabel ?label .
    VALUES ?type {
        am4:Node am4:Device am4:SystemSoftware am4:Path
        am4:CommunicationNetwork am4:DistributionNetwork
        am4:Equipment am4:Facility am4:TechnologyInterface
        am4:Artifact am4:Material
    }
    OPTIONAL { ?element skos:definition ?description }
    OPTIONAL {
        ?element am4:assignedTo ?at .
        ?at skos:prefLabel ?assignedTo .
        FILTER(lang(?assignedTo) = "en")
    }
    FILTER(lang(?label) = "en")
} ORDER BY ?type ?label

5 5. Cross-Domain Overview

Cross-domain serving and realization relationships.

Viewpoint: LayeredVP Result key: crossDomainOverview

SPARQL Query

PREFIX am4:  <https://meta.linked.archi/archimate4/onto#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?source ?sourceLabel ?relType ?target ?targetLabel WHERE {
    {
        ?source am4:serves ?target .
        BIND("serves" AS ?relType)
    } UNION {
        ?source am4:realizes ?target .
        BIND("realizes" AS ?relType)
    }
    ?source skos:prefLabel ?sourceLabel .
    ?target skos:prefLabel ?targetLabel .
    FILTER(lang(?sourceLabel) = "en")
    FILTER(lang(?targetLabel) = "en")
} ORDER BY ?relType ?sourceLabel

6 6. Implementation & Deployment

Work packages, deliverables, plateaus, and artifact deployment.

Viewpoint: ImplementationDeploymentVP Result key: implementationDeployment

SPARQL Query

PREFIX am4:  <https://meta.linked.archi/archimate4/onto#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?element ?label ?type ?description ?realizes ?deployedOn WHERE {
    ?element a ?type ; skos:prefLabel ?label .
    VALUES ?type {
        am4:WorkPackage am4:Deliverable am4:Plateau
        am4:Artifact am4:Node am4:Device am4:SystemSoftware
    }
    OPTIONAL { ?element skos:definition ?description }
    OPTIONAL {
        ?element am4:realizes ?rl .
        ?rl skos:prefLabel ?realizes .
        FILTER(lang(?realizes) = "en")
    }
    OPTIONAL {
        ?element am4:assignedTo ?dep .
        ?dep skos:prefLabel ?deployedOn .
        FILTER(lang(?deployedOn) = "en")
    }
    FILTER(lang(?label) = "en")
} ORDER BY ?type ?label

Architecture Definition Document

Sections

Architecture Requirements Specification

Architecture Principles Document