Linked.Archi

Deliverable Templates

Deliverable Templates

https://meta.linked.archi/c4/deliverable-templates#

System Overview Document

A C4-based system overview document progressing from high-level context through containers to deployment. Suitable for onboarding new team members and architecture reviews.

Template: templates/system-overview-document.md.hbs
Required Viewpoints: SystemContext ContainerDiagram C4Deployment
Target Purposes: Informing
Available Formats: MarkdownFormat, HTMLFormat

Sections

1 1. System Context
Who uses the system and what other systems does it interact with.
Viewpoint: SystemContext Result key: systemContext
SPARQL Query 
PREFIX c4:   <https://meta.linked.archi/c4/onto#>
PREFIX arch: <https://meta.linked.archi/core#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?element ?label ?type ?description ?uses WHERE {
    ?element a ?type ;
             skos:prefLabel ?label .
    VALUES ?type { c4:Person c4:SoftwareSystem }
    OPTIONAL { ?element skos:definition ?description }
    OPTIONAL {
        ?element c4:uses ?target .
        ?target skos:prefLabel ?uses .
        FILTER(lang(?uses) = "en")
    }
    FILTER(lang(?label) = "en")
} ORDER BY ?type ?label
2 2. Container Architecture
Major technical building blocks and their communication.
Viewpoint: ContainerDiagram Result key: containers
SPARQL Query 
PREFIX c4:   <https://meta.linked.archi/c4/onto#>
PREFIX arch: <https://meta.linked.archi/core#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?element ?label ?description ?technology ?system ?uses WHERE {
    ?element a c4:Container ;
             skos:prefLabel ?label .
    OPTIONAL { ?element skos:definition ?description }
    OPTIONAL { ?element c4:technology ?technology }
    OPTIONAL {
        ?sys c4:hasContainer ?element .
        ?sys skos:prefLabel ?system .
        FILTER(lang(?system) = "en")
    }
    OPTIONAL {
        ?element c4:uses ?target .
        ?target skos:prefLabel ?uses .
        FILTER(lang(?uses) = "en")
    }
    FILTER(lang(?label) = "en")
} ORDER BY ?system ?label
3 3. Deployment Topology
How containers are mapped to infrastructure.
Viewpoint: C4Deployment Result key: deployment
SPARQL Query 
PREFIX c4:   <https://meta.linked.archi/c4/onto#>
PREFIX arch: <https://meta.linked.archi/core#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?container ?containerLabel ?node ?nodeLabel ?environment WHERE {
    ?container a c4:Container ;
               skos:prefLabel ?containerLabel .
    OPTIONAL {
        ?node c4:deploys ?container .
        ?node skos:prefLabel ?nodeLabel .
        FILTER(lang(?nodeLabel) = "en")
    }
    OPTIONAL { ?node c4:environment ?environment }
    FILTER(lang(?containerLabel) = "en")
} ORDER BY ?environment ?nodeLabel ?containerLabel
📄 Template Preview 
---
title: "System Overview Document"
date: "{{meta.date}}"
author: "{{meta.author}}"
status: "{{meta.status}}"
version: "{{meta.version}}"
---

# System Overview Document

{{#if meta.description}}
> {{meta.description}}
{{/if}}

| Property | Value |
|----------|-------|
| Date | {{meta.date}} |
| Author | {{meta.author}} |
| Status | {{meta.status}} |
| Version | {{meta.version}} |
| Metamodel | C4 Model |

---

## 1. System Context

Who uses the system and what other systems does it interact with.

{{#if views.systemContext.diagram}}
![System Context Diagram]({{views.systemContext.diagram}})
{{/if}}

### People & Systems

| Element | Type | Description | Uses |
|---------|------|-------------|------|
{{#each systemContext}}
| {{this.label}} | {{this.type}} | {{this.description}} | {{this.uses}} |
{{/each}}

---

## 2. Container Architecture

Major technical building blocks and their communication.

{{#if views.containers.diagram}}
![Container Diagram]({{views.containers.diagram}})
{{/if}}

### Containers

| Container | Technology | System | Description | Uses |
|-----------|------------|--------|-------------|------|
{{#each containers}}
| {{this.label}} | {{this.technology}} | {{this.system}} | {{this.description}} | {{this.uses}} |
{{/each}}

---

## 3. Deployment Topology

How containers are mapped to infrastructure.

{{#if views.deployment.diagram}}
![Deployment Diagram]({{views.deployment.diagram}})
{{/if}}

### Deployment Mapping

| Container | Deployed On | Environment |
|-----------|-------------|-------------|
{{#each deployment}}
| {{this.containerLabel}} | {{this.nodeLabel}} | {{this.environment}} |
{{/each}}

Component Design Document

A detailed design document for a specific container, showing its internal component structure and dynamic behavior.

Template: templates/component-design-document.md.hbs
Required Viewpoints: ContainerDiagram ComponentDiagram DynamicDiagram
Target Purposes: Designing
Available Formats: MarkdownFormat

Sections

1 1. Container Context
The container within its system context.
Viewpoint: ContainerDiagram Result key: containerContext
SPARQL Query 
PREFIX c4:   <https://meta.linked.archi/c4/onto#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?element ?label ?type ?description ?technology WHERE {
    ?element a ?type ;
             skos:prefLabel ?label .
    VALUES ?type { c4:Container c4:SoftwareSystem }
    OPTIONAL { ?element skos:definition ?description }
    OPTIONAL { ?element c4:technology ?technology }
    FILTER(lang(?label) = "en")
} ORDER BY ?type ?label
2 2. Component Structure
Internal components and their relationships.
Viewpoint: ComponentDiagram Result key: components
SPARQL Query 
PREFIX c4:   <https://meta.linked.archi/c4/onto#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?element ?label ?description ?technology ?container ?uses WHERE {
    ?element a c4:Component ;
             skos:prefLabel ?label .
    OPTIONAL { ?element skos:definition ?description }
    OPTIONAL { ?element c4:technology ?technology }
    OPTIONAL {
        ?cont c4:hasComponent ?element .
        ?cont skos:prefLabel ?container .
        FILTER(lang(?container) = "en")
    }
    OPTIONAL {
        ?element c4:uses ?target .
        ?target skos:prefLabel ?uses .
        FILTER(lang(?uses) = "en")
    }
    FILTER(lang(?label) = "en")
} ORDER BY ?container ?label
3 3. Dynamic Behavior
Runtime interactions for key use cases.
Viewpoint: DynamicDiagram Result key: dynamicBehavior
SPARQL Query 
PREFIX c4:   <https://meta.linked.archi/c4/onto#>
PREFIX arch: <https://meta.linked.archi/core#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?source ?sourceLabel ?target ?targetLabel ?description WHERE {
    ?source c4:uses ?target .
    ?source skos:prefLabel ?sourceLabel .
    ?target skos:prefLabel ?targetLabel .
    OPTIONAL {
        ?rel a c4:Using ;
             arch:source ?source ;
             arch:target ?target ;
             skos:definition ?description .
    }
    FILTER(lang(?sourceLabel) = "en")
    FILTER(lang(?targetLabel) = "en")
} ORDER BY ?sourceLabel ?targetLabel
📄 Template Preview 
---
title: "Component Design Document"
date: "{{meta.date}}"
author: "{{meta.author}}"
status: "{{meta.status}}"
version: "{{meta.version}}"
---

# Component Design Document

{{#if meta.description}}
> {{meta.description}}
{{/if}}

| Property | Value |
|----------|-------|
| Date | {{meta.date}} |
| Author | {{meta.author}} |
| Status | {{meta.status}} |
| Version | {{meta.version}} |
| Metamodel | C4 Model |

---

## 1. Container Context

The container within its system context.

{{#if views.containerContext.diagram}}
![Container Context]({{views.containerContext.diagram}})
{{/if}}

### Containers & Systems

| Element | Type | Technology | Description |
|---------|------|------------|-------------|
{{#each containerContext}}
| {{this.label}} | {{this.type}} | {{this.technology}} | {{this.description}} |
{{/each}}

---

## 2. Component Structure

Internal components and their relationships.

{{#if views.components.diagram}}
![Component Diagram]({{views.components.diagram}})
{{/if}}

### Components

| Component | Technology | Container | Description | Uses |
|-----------|------------|-----------|-------------|------|
{{#each components}}
| {{this.label}} | {{this.technology}} | {{this.container}} | {{this.description}} | {{this.uses}} |
{{/each}}

---

## 3. Dynamic Behavior

Runtime interactions for key use cases.

{{#if views.dynamicBehavior.diagram}}
![Dynamic Diagram]({{views.dynamicBehavior.diagram}})
{{/if}}

### Interactions

| From | To | Description |
|------|----|-------------|
{{#each dynamicBehavior}}
| {{this.sourceLabel}} | {{this.targetLabel}} | {{this.description}} |
{{/each}}
Source: linked-archi-meta • Linked.Archi