Linked.Archi Core SHACL Shapes

            SELECT $this ?context ?language (COUNT(DISTINCT ?name) AS ?count)
            WHERE {
                $this skosxl:altLabel ?name .
                ?name arch:inPresentationContext ?context ;
                      skosxl:literalForm ?form .
                BIND(LANG(?form) AS ?language)
            }
            GROUP BY $this ?context ?language
            HAVING (COUNT(DISTINCT ?name) > 1)
        

            SELECT $this ?context (COUNT(DISTINCT ?picture) AS ?count)
            WHERE {
                $this arch:altVisNotation ?picture .
                ?picture arch:inPresentationContext ?context .
            }
            GROUP BY $this ?context
            HAVING (COUNT(DISTINCT ?picture) > 1)
        

            SELECT $this ?picture ?context
            WHERE {
                $this arch:altVisNotation ?picture .
                ?picture arch:inPresentationContext ?context .
                FILTER NOT EXISTS { ?picture schema:contentUrl ?url }
            }
        

            SELECT $this ?form
            WHERE {
                $this skosxl:altLabel ?name .
                ?name skosxl:literalForm ?form .
                FILTER NOT EXISTS { $this skos:altLabel ?form }
            }
        

            SELECT $this ?vp ?rel ?endpoint ?endpointType
            WHERE {
                $this arch:viewConformsToViewpoint ?vp .
                ?rel arch:inView $this .
                ?rel a/rdfs:subClassOf* arch:QualifiedRelationship .

                { ?rel arch:source ?endpoint . }
                UNION
                { ?rel arch:target ?endpoint . }

                ?endpoint rdf:type ?endpointType .
                ?endpointType rdfs:subClassOf* arch:Element .
                FILTER(?endpointType != arch:Element)

                FILTER EXISTS { ?vp arch:includesConcept ?anyConcept . }

                # MINUS, not FILTER NOT EXISTS: the same results (?endpoint and ?vp are bound
                # above), and much faster on a large model.
                MINUS {
                    ?endpoint rdf:type/rdfs:subClassOf* ?allowedType .
                    ?vp arch:includesConcept ?allowedType .
                }
            }
        

            SELECT $this ?vp ?element ?elementType WHERE {
                $this arch:viewConformsToViewpoint ?vp .
                ?element arch:inView $this .
                ?element rdf:type ?elementType .
                ?elementType rdfs:subClassOf* arch:Element .
                FILTER(?elementType != arch:Element)

                FILTER EXISTS { ?vp arch:includesConcept ?anyConcept . }

                # MINUS, not FILTER NOT EXISTS: the same results (?element and ?vp are bound
                # above), and much faster on a large model.
                MINUS {
                    ?element rdf:type/rdfs:subClassOf* ?allowedType .
                    ?vp arch:includesConcept ?allowedType .
                }
            }
        

            SELECT $this ?vp ?viewType
            WHERE {
                $this arch:viewConformsToViewpoint ?vp .
                $this rdf:type ?viewType .
                ?viewType rdfs:subClassOf* arch:View .
                FILTER(?viewType != arch:View)
                FILTER NOT EXISTS {
                    ?vp arch:viewType ?allowedType .
                    ?viewType rdfs:subClassOf* ?allowedType .
                }
                FILTER EXISTS {
                    ?vp arch:viewType ?anyType .
                }
            }