Zachman Framework Deliverable Templates

EA Artifact Coverage Report (Zachman)

A coverage report that classifies all architecture artifacts in the knowledge graph by their Zachman perspective (row) and interrogative (column), identifies which cells are populated and which are gaps, and produces a 6×6 coverage matrix. Useful for EA practice maturity assessment and artifact portfolio management.

Target Purposes: Governing

Available Formats: MarkdownFormat, HTMLFormat

Sections

1 1. Coverage Matrix

6×6 matrix showing artifact count per cell. Rows are perspectives (Planner through Worker), columns are interrogatives (What through Why). Cells with zero artifacts are highlighted as gaps.

SPARQL Query

PREFIX zach: <https://meta.linked.archi/zachman#>
PREFIX arch: <https://meta.linked.archi/core#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?perspective ?perspLabel ?interrogative ?intLabel
       (COUNT(DISTINCT ?artifact) AS ?count)
WHERE {
    ?perspective skos:broader zach:Perspective ;
                 skos:prefLabel ?perspLabel .
    ?interrogative skos:broader zach:Interrogative ;
                   skos:prefLabel ?intLabel .
    OPTIONAL {
        ?artifact arch:viewpointCoversAspect ?interrogative ; arch:viewpointFromPerspective ?perspective .
    }
}
GROUP BY ?perspective ?perspLabel ?interrogative ?intLabel
ORDER BY ?perspective ?interrogative

2 2. Gap Analysis

Lists all Zachman cells (perspective × interrogative) that have no artifacts classified against them. These represent potential coverage gaps in the EA practice.

SPARQL Query

PREFIX zach: <https://meta.linked.archi/zachman#>
PREFIX arch: <https://meta.linked.archi/core#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?perspective ?perspLabel ?interrogative ?intLabel
WHERE {
    ?perspective skos:broader zach:Perspective ;
                 skos:prefLabel ?perspLabel .
    ?interrogative skos:broader zach:Interrogative ;
                   skos:prefLabel ?intLabel .
    FILTER NOT EXISTS {
        ?artifact arch:viewpointCoversAspect ?interrogative ; arch:viewpointFromPerspective ?perspective .
    }
}
ORDER BY ?perspective ?interrogative

3 3. Artifacts by Perspective

For each perspective (row), lists all artifacts classified against it with their interrogative classification and labels.

SPARQL Query

PREFIX zach: <https://meta.linked.archi/zachman#>
PREFIX arch: <https://meta.linked.archi/core#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?perspective ?perspLabel ?artifact ?artifactLabel ?interrogative ?intLabel
WHERE {
    ?artifact arch:viewpointCoversAspect ?interrogative ; arch:viewpointFromPerspective ?perspective ;
              skos:prefLabel ?artifactLabel .
    ?perspective skos:broader zach:Perspective ;
                 skos:prefLabel ?perspLabel .
    ?interrogative skos:broader zach:Interrogative ;
                   skos:prefLabel ?intLabel .
}
ORDER BY ?perspective ?interrogative ?artifactLabel

4 4. Summary Statistics

Total artifact count, coverage percentage (populated cells / 36), and distribution by perspective and interrogative.

SPARQL Query

PREFIX zach: <https://meta.linked.archi/zachman#>
PREFIX arch: <https://meta.linked.archi/core#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT
    (COUNT(DISTINCT ?artifact) AS ?totalArtifacts)
    (COUNT(DISTINCT ?cell) AS ?populatedCells)
WHERE {
    {
        SELECT (CONCAT(STR(?p), "-", STR(?i)) AS ?cell) ?artifact
        WHERE {
            ?artifact arch:viewpointCoversAspect ?i ; arch:viewpointFromPerspective ?p .
            ?p skos:broader zach:Perspective .
            ?i skos:broader zach:Interrogative .
        }
    }
}